用XMLHTTP Post/Get HTML页面时的中文乱码之完全Script解决方案

以前我曾经贴过一篇用XMLHTTP Post Form 的帖子，那里的代码中我Post E文的Value毫无问题，但是后来发现Post含有中文的表单时会出现乱码，原因当然是UTF-8 和GB2312 之间的转换问题了！TNND，打倒GB2312！大家都用UTF8多好。

用XMLHTTP Post Form时的表单乱码有两方面的原因——Post表单数据时中文乱码；服务器Response被XMLHTTP不正确编码引起的乱码。换句话说，本文主要解决两个问题——怎样正确Post中文内容&怎样正确显示得到的中文内容。

Part I Post中文内容

先看看E文的表单是怎么提交的：

1<script language="JavaScript">   
2strA = "submit1=Submit&text1=scsdfsd";   
3var oReq = new ActiveXObject("MSXML2.XMLHTTP");   
4oReq.open("POST","http://ServerName/VDir/TstResult.asp",false);   
5oReq.setRequestHeader("Content-Length",strA.length);   
6oReq.setRequestHeader("CONTENT-TYPE","application/x-www-form-urlencoded");   
7oReq.send(strA);   
8</script>

如果把strA = "submit1=Submit&text1=scsdfsd";换成：
strA = "submit1=Submit&text1=中文";

你会发现提交上去的东东根本不对，ASP中Request.Form("Text1"）根本取不到值。俺用Request.BinaryRead把一个HTML Form中的Post内容写出来看了看，才发现问题——Form提交时也要编码的，编码后的中文是类似于%??%??的转义字符，比如“中文”就被编码为：%D6%D0%CE%C4。呵呵，也怪俺笨，人家CONTENT-TYPE里明明写的清清楚楚——application/x-www-form-urlencoded，urlencoded嘛当然就是这个样子了。既然这样,那我们也知道该怎么办了——自己做转换，代码见下：

 1<script language="VBScript">   
 2Function URLEncoding(vstrIn)   
 3strReturn = ""   
 4For i = 1 To Len(vstrIn)   
 5ThisChr = Mid(vStrIn,i,1)   
 6If Abs(Asc(ThisChr)) < &HFF Then   
 7strReturn = strReturn & ThisChr   
 8Else   
 9innerCode = Asc(ThisChr)   
10If innerCode < 0 Then   
11innerCode = innerCode + &H10000   
12End If   
13Hight8 = (innerCode And &HFF00)\ &HFF   
14Low8 = innerCode And &HFF   
15strReturn = strReturn & "%" & Hex(Hight8) & "%" & Hex(Low8)   
16End If   
17Next   
18URLEncoding = strReturn   
19End Function   
20  
21strA = URLEncoding("submit1=Submit&text1=中文")   
22oReq = CreateObject("MSXML2.XMLHTTP")   
23oReq.open "POST","http://ServerName/VDir/TstResult.asp",false   
24oReq.setRequestHeader "Content-Length",Len(strA)   
25oReq.setRequestHeader "CONTENT-TYPE","application/x-www-form-urlencoded"   
26oReq.send strA   
27</script>

（在这里俺把前面的JavaScript的代码改成了VBScript，不是吃饱了撑的没事干，原因见后）

Part II.正确显示得到的中文内容

OK，如果你在Server端把Form的内容写到数据库/文件的话，你在那里看到的中文毫无问题，但是，假如你想看看Server的Response——问题来了：如果Response的结果不是XML，XMLHTTP.responseXML里当然是不会有东东的，那就用responseText好了，在代码的最后加一句：

alert(oReq.responseText)
看看俺们辛勤劳动的结果 :P

但是但是.....怎么所有的中文全变成了方格? （我打不出来，有兴趣自己去试，也不用Post，Get一个含有中文的网页就可以发现了。）

原因很简单：XMLHTTP得到Response时假定Response是UTF8编码的，如果Response是XML，那还可以通过encoding来指定编码，但HTML就不行了。（见鬼的GB2312，再次打倒！）所以它把含GB2312编码的HTML当成UTF8格式，不出错才有鬼！

不过好在还有补救的办法：XMLHTTP的responseBody 属性里包含的可是未解码的Resonse——"a raw undecoded bytes as received directly from the server" ：），唯一的问题是，responseBody返回的是一个unsigned bytes数组，我们怎么去访问它，怎么把它转换成BSTR？

这就是为什么我在上面把代码改成VBScript的原因——VBScript Can do it,but JavaScript Cannot!

代码见下：

 1<script language="VBScript">   
 2Function URLEncoding(vstrIn)   
 3strReturn = ""   
 4For i = 1 To Len(vstrIn)   
 5ThisChr = Mid(vStrIn,i,1)   
 6If Abs(Asc(ThisChr)) < &HFF Then   
 7strReturn = strReturn & ThisChr   
 8Else   
 9innerCode = Asc(ThisChr)   
10If innerCode < 0 Then   
11innerCode = innerCode + &H10000   
12End If   
13Hight8 = (innerCode And &HFF00)\ &HFF   
14Low8 = innerCode And &HFF   
15strReturn = strReturn & "%" & Hex(Hight8) & "%" & Hex(Low8)   
16End If   
17Next   
18URLEncoding = strReturn   
19End Function   
20  
21Function bytes2BSTR(vIn)   
22strReturn = ""   
23For i = 1 To LenB(vIn)   
24ThisCharCode = AscB(MidB(vIn,i,1))   
25If ThisCharCode < &H80 Then   
26strReturn = strReturn & Chr(ThisCharCode)   
27Else   
28NextCharCode = AscB(MidB(vIn,i+1,1))   
29strReturn = strReturn & Chr(CLng(ThisCharCode) * &H100 + CInt(NextCharCode))   
30i = i + 1   
31End If   
32Next   
33bytes2BSTR = strReturn   
34End Function   
35  
36strA = URLEncoding("submit1=Submit&text1=中文")   
37oReq = CreateObject("MSXML2.XMLHTTP")   
38oReq.open "POST","http://ServerName/VDir/TstResult.asp",false   
39oReq.setRequestHeader "Content-Length",Len(strA)   
40oReq.setRequestHeader "CONTENT-TYPE","application/x-www-form-urlencoded"   
41oReq.send strA   
42alert bytes2BSTR(oReq.responseBody)   
43</script>

嘿嘿，是不是很简单啊，用这个再试试看？一切OK！

（顺便说说byte()，这个东东在VBScript里的表现只能用妖来形容——对它调用VarType 返回8209——vbArray + vbByte,用LBound、UBound能拿到数组的上界下界，但是就是不能用name(i)的形式访问，搞得我以为在Script里根本没法处理这种类型，在bytes2BSTR函数里可以看到我是把它当成String来处理的——LenB/MidB什么的，发现这点纯属意外——我开始往这个函数里传的是XMLHTTP.responseText，想一个Byte一个Byte地看看里面到底有点什么，后来一时性起把responseText改成responseBody，结果就中奖了，哈哈）

最后的废话：
1、以上代码在MSXML Parser 3 Release＋VBScript 5.5环境下通过。那位兄弟有早一点版本的Script可以帮我试试看能不能成。
2、一直以为JavaScript vs VBScript应该是JavaScript略好，所以有时候想彻底抛弃VBScript，ASP Server/Client统统用JavaScript，看来未必是个好主意。