龙卷风
关键字 :COM+ 事务
在三层或者多层的架构应用中 ,COM+ 的事务功能运用的比较多。
COM+ 事务的功能是非常强大的。 COM+ 使用 Microsoft Distributed Transaction Coordinator(DTC) 作为事务管理器和事务协调器在分布式环境中运行事务。 COM+ 事务的强大功能表现在:可以在多个数据库中操作数据,处理消息队列等,把这些操作作为一个原子操作。他是一个基于操作系统级别的事务。
我们用一个例子来说明 COM+ 的事务。
第一步 :
首先打开 SqlServer2000, 建立数据库 Test
表的 Sql 脚本如下
CREATE TABLE [dbo].[test1] (
[a] [int] NOT NULL ,
[b] [int] NULL
) ON [PRIMARY]
GO
CREATE TABLE [dbo].[test2] (
[a] [int] NOT NULL , 主键
[b] [int] NULL
) ON [PRIMARY]
GO
两张表的唯一区别就是 test2 有一个主键,而 test1 没有
初始化没有数据。
第二步:
然后打开 vb6, 新建 Activex Dll 工程。工程名修改为 TestComTrans, 类名修改为 Class1
修改 Class1 的属性 MTSTransactionMode 为 2-RequireTransaction, 这一步很重要。
也可以不用选择,按照默认的设置,后面在 COM+ 容器中设置事务。
引用 ”Microsoft Activex Data Object 2.7 Library” 对象库和 ”COM+ Services Type Library”
代码如下:
Option Explicit
Public Sub Add()
On Error GoTo errnumber:
Dim objCtx As ObjectContext
Set objCtx = GetObjectContext()
Dim Conn As ADODB.Connection
Set Conn = New ADODB.Connection
Conn.Open "Provider=SQLOLEDB.1;Persist Security Info=False;User ID=sa;Initial Catalog=test;Data Source=localhost"
‘ 在这里处理数据
Conn.Execute "insert into test1(a,b) values(1,1)"
Conn.Execute "update test1 set b= b + 1"
Conn.Execute "insert into test2(a,b) values(1,1)"
Conn.Execute "update test2 set b= b + 1"
objCtx.SetComplete ' 事务成功提交
If Not Conn Is Nothing Then
If Conn.State = 1 Then
Conn.Close
End If
Set Conn = Nothing
End If
Exit Sub
errnumber:
If Not Conn Is Nothing Then
If Conn.State = 1 Then
Conn.Close
End If
Set Conn = Nothing
End If
objCtx.SetAbort ' 事务失败回滚
Err.Raise Err.Number, " 事务失败会滚 , 原因 : ", Err.Description
End Sub
编译成 TestComTrans.Dll 文件 , 系统自动会注册。
否则就手工注册 Regsvr 32 f :\test\ TestComTrans.dll
第三步:部署
在控制面板中找到管理工具,打开后就可以看到组件服务。
先创建一个 COM+ 应用程序的名字 , 然后再新建组件,使用组件安装向导的时候,请使用安装新组件。如果此时我们的组件中设置 MTSTransactionMode 为 2-RequireTransaction, 当组件放入 COM+ 管理器中,它会自动把组件的 Transaction 属性设置为 Required( 必需 ) ,只有选择安装新组件的时候,这种缺省设置才会生效。
如果组件中没有设置事务属性,那么这时也可以在 COM+ 管理器中设置。
第三步:测试
我们打开 vb 新建一个标准 exe 工程 , 添加一个按钮即可
使用后期绑定来测试
代码如下:
Option Explicit
Private Sub Command1_Click()
Dim obj As Object
On Error GoTo errhander
Set obj = CreateObject("TestComTrans.Class1")
Call obj.Add
MsgBox " 事务成功 "
Exit Sub
errhander:
MsgBox Err.Source + Err.Description, vbOKOnly, Err.Number
End Sub
然后我们运行,第一次点击按钮的时候,会提示事务成功,看一下数据库,每个表中都有一条记录是 1 和 2 。第二次点击按钮的时候,由于 test2 中有主键,插入重复数据导致主键冲突,事务会滚,这是 test1 表中的数据也自动会滚。从而保证了数据的一致性。
第四步:验证
我们可以看一下事务的处理过程,打开组件管理,并选择分布式事务处理协调器节点下面的事务统计数据节点。可以看到事务成功的提交量和数务失败的中止量以及汇总的结果。
常见的错误
1. 如果这段代码在类模块中执行或者编译注册后 vb 引用执行。
objCtx.SetAbort 均报错:实时错误 91 ,未设置对象变量或者 with block 变量 .
正确的方法:
必须把这种组件注册到组件服务器中,则上述代码可以执行。
顺便解释一下
配置型组件与非配置型组件
如果一个组件被安装到 COM+ 组件服务器中,我们称这种组件为配置型组件。这种组件可以充分利用 COM+ 服务,当组件被安装后,系统在一个系统编目表中为它分配一个称为 COM+ 注册数据库 (regDB) 的配置文件 . 该编目表保存着为组件以及 COM+ 应用所配置的属性设置。
非配置型组件与 COM+ 属性没有相互关联。非配置型组件不安装到 COM+ 应用中,而以一种与 COM 早期版本兼容的方式注册,可以看作以 regsvr32 方式注册。非配置型组件不能利用 COM+ 的服务。
2. 必须在组件管理器中的组件的事务支持的选项选择必需或者要求新建,否则事务不会执行成功。